飲食店の原価計算をExcelで ― 材料の値段を変えるだけで原価率が出る表

シクミヤの福田です。当記事では、飲食店の原価計算をExcelで自動にする表の作り方を、無料のテンプレートつきで解説します。

1. 飲食店の原価計算は「原価÷売価」から
2. 手作業の表で起きること
3. Excelの表を3枚作る手順
4. 値上げの影響を1か所で見る
5. 数字がずれやすい4つの所
6. 実際の原価率と比べる
7. よくある質問
8. まとめ

XLSX飲食店の原価計算テンプレート（無料）Excel形式・マクロなし・登録不要。記入例は架空です

開いて数字が出ないときは、画面上の「編集を有効にする」を押してください。

飲食店の原価計算は「原価÷売価」から

① 1人前の材料費材料ごとの金額を足す

② 売価で割る税抜きの売価で

③ 原価率売価の何%が材料費か

手作業の表で起きること

親子丼の原価.xlsx（黄色＝手で入れる、赤＝古いままの値段）

	A	B	C	D
1	材料	量	単価	金額
2	鶏もも肉	100	1.11	111
3	卵	2	25	50
4	玉ねぎ	50	0.33	17
5	米	200	0.5	100
6	調味料・油	1	30	30
7	合計			308

今までメニューごとに単価を入れる鶏肉が上がると、使う品を全部直す。直し忘れに気づけない

これから値段は「材料」の表に1回だけ1か所変えると、全メニューの原価率が変わる

Excelの表を3枚作る手順

材料値段はここだけ

レシピ1人前で使う量

メニュー原価率が自動で出る

エクセルでの自動化全体の選び方は「エクセル自動化の方法5つ」にまとめています。

1. 「材料」に値段を入れる

   	A	B	C	D	E	F
   1	材料	値段	量	単位	使える割合	単価
   2	鶏もも肉	2,000	2,000	g	90%	1.11
   3	米	2,500	5,000	g	100%	0.50
   5	卵	250	10	個	100%	25.00

   F2=IF(COUNT(B2,C2,E2)<3,"",B2/C2/E2)仕入れ値÷量÷使える割合。下の行へコピー

2. 「レシピ」に1材料1行で入れる

   A列とB列はプルダウンで選びます。名前の打ち間違いを防ぐためです。

   	A	B	C	D	E
   1	メニュー	材料	量	単位	材料費
   6	親子丼	鶏もも肉	100	g	111
   7	親子丼	卵	2	個	50
   8	親子丼	玉ねぎ	50	g	17
   9	親子丼	米	200	g	100
   10	親子丼	調味料・油	1	食	30

   D2=IF(B2="","",IFERROR(VLOOKUP(B2,材料!$A$2:$F$101,4,FALSE),"確認"))材料の単位を持ってくる

   E2=IF(OR(B2="",C2=""),"",IFERROR(C2*VLOOKUP(B2,材料!$A$2:$F$101,6,FALSE),"確認"))量×1単位の原価

3. 「メニュー」で原価率を見る

   	A	B	C	D	E
   1	目標の原価率	35%
   3	メニュー	売価	原価	原価率	判定
   4	からあげ定食	900	345	38.3%	見直し
   5	親子丼	900	308	34.2%	OK
   6	だし巻き卵	500	105	21.0%	OK

   C4=IF(A4="","",SUMIF(レシピ!$A$2:$A$301,A4,レシピ!$E$2:$E$301))同じメニューの材料費を足す

   D4=IF(COUNT(B4,C4)<2,"",C4/B4)原価÷売価

   E4=IF(D4="","",IF(COUNTIF(レシピ!$A$2:$A$301,A4)=0,"レシピなし",IF(COUNTIFS(レシピ!$A$2:$A$301,A4,レシピ!$E$2:$E$301,"確認")>0,"材料を確認",IF(D4>$B$1,"見直し","OK"))))目標を超えたら「見直し」。材料の入れ忘れも知らせる

   G4=IF(D4="","",ROUNDUP(ROUND(C4/$B$1,0),-1))目標に合う売価（10円単位で切り上げ）

値上げの影響を1か所で見る

「材料」のB2、鶏もも肉の仕入れ値を2,000円から2,400円に変えただけの結果です。

2,000円のとき2,400円のとき

38.3%からあげ定食42.8%

34.2%親子丼36.7%（見直しに）

21.0%だし巻き卵21.0%（影響なし）

数字がずれやすい4つの所

1税込みと税抜きが混ざる仕入れ値も売価も税抜きで揃える

2皮や骨の分を忘れる「使える割合」で割る

3調味料を量り続ける1食いくらと決めて1行に

4値段を更新しない請求書が来た日に「材料」を直す

使える割合は、一度量れば決まります。皮をむく前と後の重さで割るだけです。最初の目安には、文部科学省の食品成分データベースの「廃棄率」も使えます。

実際の原価率と比べる

ここまでの表は、レシピどおりに作った場合の数字です。月に1回、在庫を数えて実際の数字と比べます。

① 在庫を数える月初と月末の金額

② 使った金額を出す月初＋仕入れ−月末

③ 売上で割る実際の原価率

表の数字より高ければ、盛りすぎ・廃棄・まかない・値段の更新もれのどれかが疑えます。

よくある質問

まとめ

• 原価率は1人前の材料費÷税抜きの売価
• 値段は「材料」の表に1回だけ入れ、レシピとメニューは自動で計算する
• 値上げは1か所直せば、影響する品と売価の目安まで出る
• 仕入れ値と売価は税抜きで揃え、皮や骨の分も入れる
• 月に1回、在庫を数えて実際の原価率と比べる

参考にした資料

• VLOOKUP 関数（Microsoft サポート）
• SUMIF 関数（Microsoft サポート）
• COUNTIFS 関数（Microsoft サポート）
• IFERROR 関数（Microsoft サポート）
• ROUND 関数（Microsoft サポート）
• ROUNDUP 関数（Microsoft サポート）
• ドロップダウン リストを作成する（Microsoft サポート）
• 小企業の経営指標調査 飲食店，宿泊業（日本政策金融公庫）
• No.6102 消費税の軽減税率制度（国税庁）
• 飲食料品に係る2年間の消費税率引下げに関するQ&A（国税庁・令和8年9月）
• 令和7年分 青色申告の決算の手引き（国税庁）
• 食品成分データベース（文部科学省）